MQ2 Macro Housekeeping

[Booges]

Hey guys,

So as part of a way to fully saturate myself to remember syntax and macro code quickly, I'm doing a little housekeeping project for all macros that are included with the MMOBugs compile in an effort to make sure that when new or existing members download the compile, they have macros at their disposal that aren't broken or frustrate them. As someone coming back from being gone a long time, this can especially be beneficial for newer folks test driving MQ2 who might be considering membership but don't understand the language well enough to troubleshoot it right out of the box.

Anyone who is willing to lend a hand is more than welcome to do so. I've created a tracker that lists all of the current ones. Once we shore these up, we can consider expanding to some of the other macros that are available on these forums but may be difficult to locate among all the threads (with Fry's approval, of course).

Post any notes or comments you have with regards to the core compile-included macros at this time, either here or directly on the spreadsheet. Additionally, feel free to post any use cases that you'd prefer a macro existed for by default and we can take them into consideration during phase 2.

Tracker: MQ2 Macro Tracker

 

[aspire2008]

I use a completely different combine.mac, that PeteSampras added a few modifications too, that I really wanted, since I do a lot of tradeskilling. Its far better than the old combine.mac

Link to discussion

Here is the code:

|===========================================| 
| V2.1                                      | 
|___________________________________________| 
|fletch.mac MQ2Data Compliant by Fuergrissa | 
|#Events updated 12-05-04                   | 
|___________________________________________| 

#Event SkillUp "You have become better at #1#! (#2#)" 
#Event nocomp "#*#You are missing#*#" 
#Event SkillTrivial "#*#You can no longer advance your skill from making this item#*#" 
#Event FullInventory "#*#There was no place to put that#*#" 
#Event SkillFailure "#*#You lacked the skills#*#" 
#Event SkillSuccess "#*#You have fashioned the items together to create something new#*#" 
#Event SkillSalvage "#*#You failed the combine but managed to recover#*#" 

Sub Main 
    /declare SkillSalvageCounter int outer
    /declare SkillFailCounter int outer 
    /declare SkillSuccessCounter int outer 
    /declare SuccessRate int outer 
    /declare SalvageRate int outer
    /declare FailRate int outer
    /declare TotalAttempts int outer
    /declare EndOnTrivial bool outer FALSE

:mainloop 
    /doevents 
    /if (${Cursor.ID}) {
        /autoinv
        /goto :mainloop 
        }
    /call Combine 
    /goto :mainloop 
:onExit
/call DisplayStats
/end
/end 
/return

Sub Combine 
    /notify TradeskillWnd CombineButton leftmouseup 
    /delay 2 
    /if (${Cursor.ID}) /autoinv 
/return 

Sub DisplayStats 
    /echo Combine Statistics - Successes: ${SkillSuccessCounter}, Failures: ${SkillFailCounter} , Salvages: ${SkillSalvageCounter}
    /varcalc TotalAttempts ${SkillFailCounter} + ${SkillSuccessCounter} 
    /varcalc SuccessRate ${SkillSuccessCounter} / ${TotalAttempts} * 100 
    /varcalc FailRate ${SkillFailCounter}/${TotalAttempts}*100
    /varcalc SalvageRate ${SkillSalvageCounter}/${TotalAttempts}*100
    /echo Success Rate: ${SuccessRate} % out of ${TotalAttempts} attempts 
    /echo Salvage Rate: ${SalvageRate} % out of ${TotalAttempts} attempts
    /echo Fail Rate: ${FailRate} % out of ${TotalAttempts} attempts
/return 

Sub Event_SkillUp(SkillUpText,TheSkill,int Amount) 
    /popup ${TheSkill} increased - ${Amount} 
    /echo ${TheSkill} increased - ${Amount} 
/return
      
      
Sub Event_nocomp 
    /echo "You have run out of Componants. ((Ending Macro)) " 
    /popup You have run out of Componants. ((Ending Macro))    
    /if (${Cursor.ID}) /autoinv 
    /call DisplayStats 
/end 

Sub Event_SkillTrivial
    /if (!${EndOnTrivial}) /return
    /echo "You can no longer advance your skill from making this item. ((Ending Macro))" 
    /popup You can no longer advance your skill from making this item. ((Ending Macro))    
    /if (${Cursor.ID}) /autoinv 
    /call DisplayStats 
    /end
/return 

Sub Event_FullInventory 
    /echo "Your inventory is full, ((( Ending Macro ))) " 
    /popup Your inventory is full, ((( Ending Macro ))) 
    /call DisplayStats 
    /end
/return 

Sub Event_SkillFailure 
    /varcalc SkillFailCounter ${SkillFailCounter}+1 
/return 

Sub Event_SkillSuccess  
    /varcalc SkillSuccessCounter ${SkillSuccessCounter}+1 
/return

Sub Event_SkillSalvage
    /varcalc SkillSalvageCounter ${SkillSalvageCounter}+1
/return