Bind wound, getting drunk and begging.

[wilbunk]

I know im kinda being a old mudcrab about this but there seems not to be any new content in a while on this stuff, so here goes.
These days.....whats the fastest way to max alcohol tolerance, bind wound, and begging. i did searches but things led me to stuff that didnt exist anymore. and while i THINK i understood macros i tried putting one together for drinking and binding wound together i failed so very.....very horribly. Any help is appreciated, thank you

 

[supertimmy]

for begging go to barindu. right outside the tipt entrace there is a non kos mob. some kind of golem or something. i can't remember his name but he's the last one before the zone line. can't really miss him. target him. make sure you have a hotkey for beg. /macro beg.

for alcohol tolerance, fill your bags with booze. bank all your armor. go the arena. bind yourself. drink until you can't drink no more. duel and let yourself be killed by another of your toons. repeat.

bind wound sucks for melee. best place i've found is swimming in ashengate lava until near death. pop out and start bandaging. this will take forever. i've read a few posts about macros where you can nuke yourself. i don't have any details on those and if you can't nuke yourself, it's a long road.

it's been a long time since i've tried these but these worked for me personally in the past.

 

[wilbunk]

boy id sure like to know what this /macro beg thing is you are speaking of. not in my compile apparently

 

[supertimmy]

|**--------------------------------------------------------------------------------------------------------------- 
Beg.mac by Draimen 
   This macro will beg a target forever. 
   To end, simply press esc to clear your target then wait ~15 seconds.  You will then receive a report. 
   If you somehow get out of beg range, but less than 30 ft away, the macro will move you closer. 
   If you get more than 30 ft away it will end. 
   Use this macro on stationary mobs that you know will not attack you.  Onytir Seavin in N Freeport if a good one. 
   If you piss off an npc and it attacks, the macro has no way of saving you, so use wisely. 
----------------------------------------------------------------------------------------------------------------**| 

#Event fail "Your attempt at begging was unsuccessful." 
#Event skillup "You have become better at Begging#*#" 
#Event suc "You have begged#*#" 


Sub Main 

/declare failcount int outer 0 
/declare skillup int outer 0 
/declare attempt int outer 0 
/declare scount int outer 0 
/declare copper int outer 

/if (!${Target.ID}) { 
   /echo You must target an npc before using this macro! 
   /endmacro 
} 

/if (${Target.Distance}>14) { 
   /echo Too far away from target to beg, get closer and start the macro again 
   /endmacro 
} 

/echo Starting begging skillup macro on ${Target.CleanName} 

/vardata copper Me.Copper 

:begloop 
/if (!${Target.ID}) /call End 
/if (${Target.Distance}>30) { 
   /echo Target got too far out of range, ending macro 
   /call End 
} 
/if ((${Target.Distance}>14)&&(${Target.Distance}<30)) { 
   :farloop 
   /if (${Me.Sitting}) /stand 
   /face 
   /keypress forward hold 
   /delay 5 ${Target.Distance}<14 
   /keypress forward 
   /if (${Target.Distance}>14) /goto :farloop 
} 
/delay 15s ${Me.AbilityReady[begging]} 
/if ((${Target.ID})&&(${Me.AbilityReady[begging]})) /doability begging 
/varcalc attempt ${attempt}+1 
/delay 15s ${Me.AbilityReady[begging]} 
/doevents 
/goto :begloop 

/return 

Sub Event_fail 
/varcalc failcount ${failcount}+1 
/return 

Sub Event_skillup 
/varcalc skillup ${skillup}+1 
/return 

Sub Event_suc 
/varcalc scount ${scount}+1 
/return 

Sub End 
/echo You failed begging ${failcount} out of ${attempt} tries. 
/echo You succeeded in begging ${scount} out of ${attempt} tries. 
/echo You got ${skillup} skill ups. 
/echo You received ${Math.Calc[${Me.Copper}-${copper}]} copper for all your hard work. 
/endmacro 
/return

 

[[40oz]]

If you're a melee character, you can turn begging on in the MQ2Melee plugin so it just does it whenever you're fighting. Keeps mine maxed just fine.

 

[Blujahz]

You can beg from the Teleportation npc in the center of the wizzy spire in Greater Faydark.

For Bind Wounds, best to find a Berserker friend who can use their Bloodfury AA to self-damage themself. My BER can do this twice in a row and be at 25% health.

Here is the macro I used. Make sure to replace your Berseker's name in the macro (and use EQBC).

#event Healed "You cannot bandage your target past 100#*#" 

Sub Main

:again

/if (${Me.AbilityReady[Bind Wound]}) {
	/delay 3s
	/doability "Bind Wound"
}
/delay 1

/doevents

/if (${Me.Skill[Bind Wound]}<${Skill[Bind Wound].SkillCap}) /goto :again

/return

Sub Event_Healed

/bct BERSERKER_NAME //alt activate 752
/delay 2s
/bct BERSERKER_NAME //alt activate 752

/return

As for alcohol tolerance, Taron created a nice mac that will max you in a few seconds. Make sure nobody is nearby when you run it because it's obvious you're using MQ2. I run it near the brew merchants in Abysmal Sea. Change the mac to whatever you want to drink. I use short beer.

|---------------------- Coded by Taron @ MMOBugs.com ---------------------|
|-------------------------------------------------------------------------|
|- What: Maxes alcohol tolerance quickly                                 -|
|- Where: Anywhere!                                                      -|
|- How: /macro drunk                                                     -|
|- Notes: Use /docrack unlimiteddrunk on                                 -|
|-------------------------------------------------------------------------|
|-           MAKE SURE AND SET THE ALCOHOL'S NAME BELOW                  -|
|-------------------------------------------------------------------------|

#Turbo 40
Sub Main

|---
|- Change to the drink you are using
|-----------------------------------------

/declare DrinkOfChoice string outer "Short Beer"

/docrack unlimiteddrunk on

:Loop

/useitem ${DrinkOfChoice}

/if (${FindItem[${DrinkOfChoice}].InvSlot} && ${Me.Skill[Alcohol Tolerance]}<${Skill[Alcohol Tolerance].SkillCap}) /goto :Loop

/return

 

[Marnan]

It's cheesy, but Heroicing any toon gives 450 AT / 450 BW / and 425 Begging. Also gives the DON AAs and the six MPG trials. I know this because I didn't feel like doing the DON faction work yet again on one of my toons. It's the fastest way, but it also costs real cash.

 

[nickeljk]

can anyone tell me why i cant make the macro for AT work?