DoD - Into the Shadows

[Fixxer]

While trying to get explorer achievements, I found that I needed to do a mission called "Into the Shadows", where they force you into lvl20 Illsalin shrouds. The mission is incredibly difficult for a boxer such as myself.

Does anyone have any tips or tricks that will help me get past it so I can request the other missions beyond that point and get all of the traveler achievements?

 

[dewey2461]

Are you on bert?

 

[NZ2017]

I had to do this recently to get my 24 through the progression. Make a war, cleric, 4 nukers. Set them up in the room behind the red con quest npc, the Illsalin mobs (or w/e they are) will help you kill the mobs you need to kill. Pull carefully on the war so you get singles. Jump onto the cleric to get a heal casting then hop onto the wiz one by one til the mob is dead. I.e play old school as if you are alt tabbing with no automation.

If you use ISBoxer, you can make a char set for this where you broadcast the top hotbar and make assist hotkeys and nuke hotkeys etc which you hit on your puller/war. But it's no biggie if you lose chars during the mission, they insta respawn.

 

[Fixxer]

Thanks for the tip. I'll give it a try!

 

[Sum1]

Thanks for the tip. I'll give it a try!

You sure that’s actually required for explorer? Make sure to check the achievements tab for the overall DoD explorer achievement. Any checkbox that’s tabbed in isn’t actually required.

 

[MamaBear]

For explorer all you need is to go in you don't need to complete the missions..I guess you probably know this

 

[evilbarney]

you also don't need to go into any zones that are staggered on the explorer list like the wedding chapels for example or instance zones

 

[dewey2461]

I wrote a small macro to help with the LDON explorer.

You want to have two characters. Leader stays at the adventurer NPC while the toon you want to achieve with goes to the zone where the instances are.

Leader requests -> Achiever goes in to instance -> once inside drops adventure and leaves.

Repeat above.


The macro does most of the clicking for requesting and dropping.

 

[Sum1]

I wrote a small macro to help with the LDON explorer.

You want to have two characters. Leader stays at the adventurer NPC while the toon you want to achieve with goes to the zone where the instances are.

Leader requests -> Achiever goes in to instance -> once inside drops adventure and leaves.

Repeat above.


The macro does most of the clicking for requesting and dropping.

Is that macro shared here somewhere?

 

[dewey2461]

|----------------------------------------------------------------------------
| Macro : /mac ldon 
|
| Author : Dewey2461
|
| This macro is designed to help complete the LDON traveler achievements.
|
| SETUP: 
| 1. Form a group of 3 members: 1 can be a merc
| 2. Leader moves to the adventure recruiter
| 3. Right clicks the recruiter -> macro auto selects adventure ( have to manually do this first time )
| 4. Achiever moves to adventure and zones in. 
| 5. Macro detects when zoned into ldon and clicks "Leave Adventure" button -> auto broadcasts "Leave Adventure"
| 6. All members leave adventure
| 7. Macro has Leader requests next adventure in about 15s 
| 8. Achiever manually zones out.  
| 9. Goto step 3.
|
|----------------------------------------------------------------------------

#warning

#event LeaveAdv "#*#Leave adventure#*#"
Sub Event_LeaveAdv
	/if (${LeaveTM}) /return
	/if (${Window[AdventureRequestWnd].Child[AdvRqst_RequestButton].Enabled} && ${Window[AdventureRequestWnd].Child[AdvRqst_RequestButton].Text.Equal[Leave Adventure]}) {
		/echo -- Leaving Adventure
		/notify AdventureRequestWnd AdvRqst_RequestButton leftmouseup
	}
	/varset LeaveTM 3s
	/varset RequestTM 20s
/return


#event LeftAdv "#*#You have left your adventure.#*#"

Sub Event_LeftAdv
	/if (${LeaveTM}) /return
	/bc Leave adventure
/return

#event Zoned "#*#You have entered #1#.#*#"

Sub Event_Zoned(string line,string name)
	/declare key string
	/declare val string
	/declare try string
	
	/if (${name.Find[:]}) {
		/varset DoneTM 10s
		/varset val ${Window[AdventureRequestWnd].Child[AdvRqst_NPCText].Text}
		/varcalc try ${Ini["ldon.ini","try","${name}","0"]}+1
		/ini "ldon.ini"  "try" "${name}" "${try}"
	}
/return

Sub main
	/declare LeaveTM timer outer 0
	/declare RequestTM timer outer 0
	/declare DoneTM timer outer 0
	
	/echo LDON Explorer - Party Leader needs to right click Adventure Recruiter
	:Loop
		/doevents
		
		|-- We've zoned in. Now drop the adventure 
		/if (${DoneTM}>0 && ${DoneTM}<10) {
			/notify AdventureRequestWnd AdvRqst_RequestButton leftmouseup
		}

		|-- We were told to drop the instance so lets try to re "use" the npc to get next
		/if (${RequestTM}>0 && ${RequestTM}<10) /keypress use
		
		
		|-- Show the LDON adventure window 
		/if (!${Window[AdventureRequestWnd].Open}) /invoke ${Window[AdventureRequestWnd].DoOpen}

		|-- Request an adventure if we can 
		/if (${Window[AdventureRequestWnd].Child[AdvRqst_RequestButton].Enabled}) {
			/if (${Window[AdventureRequestWnd].Child[AdvRqst_RequestButton].Text.Equal[Request Adventure]}) {
				/echo -- Requesting an adventure
				/notify AdventureRequestWnd AdvRqst_RequestButton leftmouseup
			}
		}

		|-- Click Accept for Adventure
		/if (${Window[AdventureRequestWnd].Child[AdvRqst_AcceptButton].Enabled}) {
			/echo -- Accepting an adventure
			/notify AdventureRequestWnd AdvRqst_AcceptButton leftmouseup

		}
		
		|-- Click the yes|no button
		/if (${Window[ConfirmationDialogBox].Open}) {
			/notify ConfirmationDialogBox Yes_Button leftmouseup
		}
		
		|-- Click other yes|no button
		/if (${Window[LargeDialogWindow].Open}) {
			/notify LargeDialogWindow LDW_YesButton leftmouseup
		}



		/delay 5
	/goto :Loop
/return