| - PickupItem.mac (for the eqmac version of MQ2)
| - By EqMule Sep 24 2013
| - This macro will demonstrate how to pick up an item even if bags are closed
| - You can expand on this by checking ${Cursor.WornSlot[1]}
| - after the item is on the cursor, to actually equip it
| - but I leave that exercise for a more experianced macrowriter than myself.
#turbo
Sub Main
/declare ourclicky Opal Encrusted Stein
:recheck
/echo looking for a ${ourclicky}
/if (${FindItem[=${ourclicky}].ID}) {
/if (${FindItem[=${ourclicky}].IsInBag}) {
/if (${FindItem[=${ourclicky}].InvSlot.Pack.Item.Open}) {
/echo the ${ourclicky} is in a open bag
/echo we pick it up
/call PickupItem "${ourclicky}"
} else {
/echo the ${ourclicky} is in a closed bag
/echo lets open it
/call OpenBag "${ourclicky}"
/goto :recheck
}
} else {
/echo ${ourclicky} is not in a bag
/echo we can click it directly
/call PickupItem "${ourclicky}"
}
} else {
/echo no such item found
}
/return
Sub PickupItem(item)
/declare pickuptimer timer
:retrypickup
/varset pickuptimer 2s
/itemnotify ${FindItem[=${item}].InvSlot} leftmouseup
/delay 1s
:waitforcursor
/if (!${Cursor.ID}) {
/if (${pickuptimer}==0) {
/echo timed out waiting for pickup will retry
/goto :retrypickup
}
/goto :waitforcursor
}
/echo Item is on cursor
/return
Sub OpenBag(item)
/declare bagopentimer timer
:retryopenbag
/varset bagopentimer 2s
/echo opening ${FindItem[=${item}].InvSlot.Pack.Item}
/itemnotify ${FindItem[=${item}].InvSlot.Pack} rightmouseup
:waitforbagtoopen
/if (!${FindItem[=${item}].InvSlot.Pack.Item.Open}) {
/if (${bagopentimer}==0) {
/echo timed out waiting for bag to open will retry
/goto :retryopenbag
}
/goto :waitforbagtoopen
}
/return
